Le guide Oracle Forms 9i/10g

Date de publication : Juin 2005

Les blocs de données

Les blocs basés sur table ou vue simple

Définition

Concept

Mise en oeuvre

Ajout d'un bloc

Pour ajouter un bloc à la forme, double-cliquer sur le nœud Blocs de données ou faire un simple clic sur le nœud Blocs de données puis cliquer sur l'icône

Utilisation des assistants

le bloc sera basé sur une table ou une vue

• Même enregistrement indique que l'on boucle sur le même enregistrement
• Changement d'enregistrement indique que l'on saute à l'enregistrement suivant en quittant le dernier champs (Tab) ou à l'enregistrement précédent en quittant le premier champs (Shit+Tab)
• Changement de bloc de données indique que l'on saute au bloc suivant lorsque l'on quitte le dernier enregistrement (Tab) ou au bloc précédent lorsque l'on quitte le premier enregistrement (Shit+Tab)

• Aucun (bloc non basé)
• Table (table ou vue)
• Procédure (procédure stockée en base)
• Déclencheurs transactionnels (pour des sources de données non-Oracle)
• Interrogation de clause From (ordre SELECT)

• Aucun
• Table
• Procédure
• Déclencheur transactionnel

Les blocs liés par une relation

Définition

Concept

Mise en oeuvre

• En cascade permet, lors de la suppression de l'enregistrement maître de supprimer en cascade les enregistrements détail au moment du commit
• Isolée permet de supprimer un enregistrement maître sans affecter les enregistrements détail
• Non isolée indique qu'il est impossible de supprimer un enregistrement maître si un détail existe

• ON-CLEAR-DETAIL

• ON-POPULATE-DETAILS
• ON-CHECK-DELETE-MASTER

• PROCEDURE Clear_All_Master_Details()
• PROCEDURE Query_Master_Details()

Les blocs basés sur une vue complexe

Définition

Concept

• Baser le bloc sur une vue existante en base
• Baser le bloc sur une vue fictive (SUB-QUERY)

Mise en oeuvre

CREATE OR REPLACE VIEW EMP_DEPT 
( 
  EMPNO, 
  ENAME, 
  DEPTNO, 
  DNAME 
) AS 
SELECT 
  e.empno, 
  e.ename, 
  d.deptno, 
  d.dname
FROM 
  emp e, 
  dept d
WHERE 
  e.DEPTNO = d.DEPTNO
;

-------------------------------------------------
-- Gestion manuelle du DML sur la vue EMP_DEPT --
-------------------------------------------------
PROCEDURE ins_upd_emp_dept IS
  LN$Dummy PLS_INTEGER := 0 ;
BEGIN
  -- Table DEPT --
  Begin
  Select 1
  Into LN$Dummy
  From DUAL
  Where exists( select deptno from dept where deptno = :EMP_DEPT.DEPTNO ) ;
    -- Trouve, MAJ --
  	Message('Update de la table DEPT');
  	UPDATE DEPT
  	SET    DNAME = :EMP_DEPT.DNAME
  	WHERE  DEPTNO = :EMP_DEPT.DEPTNO ;
  Exception
  	When no_data_found Then
    -- Insertion --
  	Message('Insertion dans la table DEPT');
  	INSERT INTO DEPT ( DEPTNO, DNAME )
  	VALUES ( :EMP_DEPT.DEPTNO, :EMP_DEPT.DNAME ) ;
  End ;
  
  -- Table EMP --
  Begin
  Select 1
  Into LN$Dummy
  From DUAL
  Where exists( select empno from emp where empno = :EMP_DEPT.EMPNO ) ;
    -- Trouve, MAJ --
  	Message('Update de la table EMP');
  	UPDATE EMP
  	SET    ENAME = :EMP_DEPT.ENAME
  	WHERE  EMPNO = :EMP_DEPT.EMPNO ;
  Exception
  	When no_data_found Then
    -- Insertion --
  	Message('Insertion dans la table EMP');
  	INSERT INTO EMP ( EMPNO, ENAME )
  	VALUES ( :EMP_DEPT.EMPNO, :EMP_DEPT.ENAME ) ;
  End ;
  
END;

Code du déclencheur : WHEN-LIST-CHANGED
If :CTRL.CHOIX is not null Then
	:global.choix := :ctrl.choix ;
	clear_form ;
	:ctrl.choix := :global.choix ;
	Set_Block_Property('TEST2', QUERY_DATA_SOURCE_NAME, :global.CHOIX );
	go_block('TEST2');
	execute_query;
End if ;

Techniques avancées

• Vous utilisez une vue même si vous n'avez pas les droits suffisants pour la créer en base
• Vous souhaitez trier les enregistrements dans votre bloc sur une colonne qui n'appartient pas à la table principale.

CREATE OR REPLACE VIEW EMP_NDEPT 
( 
  EMPNO, 
  ENAME, 
  DEPTNO, 
  DNAME 
) AS 
SELECT 
  e.empno, 
  e.ename, 
  e.deptno, 
  d.dname
FROM 
  emp e, 
  dept d
WHERE 
  e.DEPTNO = d.DEPTNO
ORDER BY
  d.dname,
  e.ename
/

SELECT 
  e.empno, 
  e.ename, 
  e.deptno, 
  d.dname
FROM 
  emp e, dept d
WHERE 
  e.DEPTNO = d.DEPTNO
ORDER BY
  d.dname,
  e.ename
;

Les blocs basés sur procédure stockée

Définition

Concept

• Sélection des enregistrements
• Insertion
• Suppression
• Mise à jour
• Verrouillage

Mise en oeuvre

  -- Record de type EMP --
  TYPE emp_rec IS RECORD(
    Empno   emp.empno%TYPE,
    Ename   emp.ename%TYPE,
    Job     emp.job%TYPE,
    Sal     emp.sal%TYPE,
    Comm    emp.comm%TYPE);

  -- Si le bloc est basé sur un REF CURSOR --
  TYPE emp_cursor IS REF CURSOR RETURN emp_rec;

  -- Tableau d'enregistrements pour les procédures --
  TYPE emptab IS TABLE OF emp_rec INDEX BY BINARY_INTEGER;

  ----------------------------
  --  Select avec REFCURSOR --
  ----------------------------
  PROCEDURE emp_refcur
   (
      emp_data IN OUT emp_cursor
     ,p_num IN VARCHAR2
     ,p_nom IN VARCHAR2
     ,p_job IN VARCHAR2
     ,p_sal IN VARCHAR2
     ,p_com IN VARCHAR2
   ) IS
  BEGIN
    -- sauvegarde clause where --
    GC$Num := p_num ;
    GC$Nom := p_nom ;
    GC$Job := p_job ;
    GC$Sal := p_sal ;
    GC$Com := p_com ;

    OPEN  emp_data FOR SELECT empno, ename, job, sal, comm
    FROM  emp
    WHERE EMPNO LIKE Nvl( p_num || '%', EMPNO )
    AND   ENAME LIKE Nvl( p_nom || '%', ENAME )
    AND   JOB LIKE Nvl( p_job || '%', JOB )
    AND   ( SAL LIKE Nvl( p_sal || '%', SAL ) OR p_sal is null )
    AND   ( COMM LIKE Nvl( p_com || '%', COMM ) OR p_com is null )
    ORDER BY ENAME ;
  END emp_refcur;

  --------------------------------------
  -- Insertion trigger transactionnel --
  --------------------------------------
  PROCEDURE emp_insert2(t IN emptab) IS
  BEGIN
    FOR i IN t.first..t.last LOOP
	INSERT INTO emp (empno, ename, job, sal, comm)
	VALUES(t(i).empno, t(i).ename, t(i).job, t(i).sal, t(i).comm);
    END LOOP ;
  END emp_insert2;

  ----------------------------------------
  -- Mise à jour trigger transactionnel --
  ----------------------------------------
  PROCEDURE emp_update2(t IN emptab) IS
  BEGIN
	FOR i IN t.first..t.last LOOP
		UPDATE emp
		SET  ename  = t(i).ename,
		     job    = t(i).job,
		     sal    = t(i).sal,
		     comm   = t(i).comm
		WHERE empno = t(i).empno;
    END LOOP ;
  END emp_update2 ;

  -----------------------------------
  -- Delete trigger transactionnel --
  -----------------------------------
  PROCEDURE emp_delete2( t IN emptab ) IS
  BEGIN
	FOR i IN t.first..t.last LOOP
		DELETE FROM emp
		WHERE  empno = t(i).empno;
	END LOOP ;
  END emp_delete2;

  ---------------------------------
  -- Lock trigger transactionnel --
  ---------------------------------
  PROCEDURE emp_lock2( t IN emptab ) IS
    v_rownum NUMBER;
    verrou exception;
    pragma exception_init ( verrou, -54 ) ;
  BEGIN
	FOR i IN t.first..t.last LOOP
		SELECT empno
		INTO   v_rownum
		FROM   emp
		WHERE  empno = t(i).empno
		FOR UPDATE OF ename NOWAIT;
	END LOOP ;
  EXCEPTION
	When verrou then
		Raise_Application_Error( -20100, '^Verrouillage de l''enregistrement impossible^' ) ;
  END emp_lock2;

  -------------------------
  -- Select avec tableau --
  -------------------------
  PROCEDURE emp_query(emp_data IN OUT emptab) IS
    ii NUMBER;
    CURSOR empselect IS
      SELECT empno, ename, job, sal, comm FROM emp
	  ORDER BY ename ;
  BEGIN
    OPEN empselect;
    ii := 1;
    LOOP
      FETCH empselect INTO
        emp_data( ii ).empno,
        emp_data( ii ).ename,
        emp_data( ii ).job,
        emp_data( ii ).sal,
        emp_data( ii ).comm;
      EXIT WHEN empselect%NOTFOUND;
      ii := ii + 1;
    END LOOP;
  END emp_query;

Techniques avancées

Déclencheur ON-ERROR
Declare
	LC$Msg Varchar2(2000) ;
Begin	

If DBMS_ERROR_CODE = -20100 Then
	-- Récupération du message inséré dans Raise_Application_Error --
      LC$Msg := substr(DBMS_ERROR_TEXT, 
            instr(DBMS_ERROR_TEXT,'^')+ 1 ,
            ( instr(DBMS_ERROR_TEXT,'^',-1) - instr(DBMS_ERROR_TEXT,'^') - 1) ) ;

	message(LC$Msg, acknowledge ) ;
Else
	message('erreur : ' || DBMS_ERROR_TEXT, acknowledge ) ;
End if ;

End ;

  ---------------------------------
  -- Lock trigger transactionnel --
  ---------------------------------
  PROCEDURE emp_lock2( t IN emptab ) IS
    v_rownum NUMBER;
    verrou exception;
    pragma exception_init ( verrou, -54 ) ;
  BEGIN
	FOR i IN t.first..t.last LOOP
	  SELECT empno
	  INTO   v_rownum
	  FROM   emp
	  WHERE  empno = t(i).empno
	  FOR UPDATE OF ename NOWAIT;
	END LOOP ;
  EXCEPTION
    When verrou then
	  Raise_Application_Error( -20100, '^Verrouillage de l''enregistrement impossible^' ) ;
  END emp_lock2;

• QUERY_PROCEDURE
• INSERT_PROCEDURE
• UPDATE_PROCEDURE
• DELETE_PROCEDURE
• LOCK_PROCEDURE

• Erreurs insertion : à partir de -20200
• Erreurs mise à jour : à partir de -20300
• Erreurs suppression : à partir de -20400

Les blocs basés sur une collection

Définition

Concept

• ON-INSERT
• ON-UPDATE
• ON-DELETE

Mise en oeuvre

-- Type d'un emplacement --
CREATE TYPE TYP_CASE AS OBJECT
 (
   EMP   VARCHAR2(10),
   QTE    NUMBER
 )
/
 
-- Table d'emplacements --
CREATE TYPE TAB_TYP_CASE AS TABLE OF TYP_CASE
/

-- Table des articles --
CREATE TABLE ARTICLES
 (
   CODE    VARCHAR2(20),
   LIBELLE VARCHAR2(100),
   PRIX    NUMBER(8,2),
   QTETOT  NUMBER(8),
   CASES   TAB_TYP_CASE
 )
 NESTED TABLE CASES STORE AS CASES_NT
 STORAGE
 (
   INITIAL 5K
   NEXT 5K
   PCTINCREASE 0
   MINEXTENTS 1
   MAXEXTENTS 500
 )
/

• EMP de type Varchar2(20)
• QTE de type NUMBER

Déclencheur On-Insert
------------------------------------------------
--  l' insertion est effectuée explicitement  --
--  car le nouvel enregistrement ne peut pas  --
--  contenir une collection NULL              --
------------------------------------------------
INSERT INTO ARTICLES
  (
    CODE,
    LIBELLE,
    PRIX,
    QTETOT,
    CASES
  )
  VALUES
  (
    :ARTICLES.CODE,
    :ARTICLES.LIBELLE,
    :ARTICLES.PRIX,
    :ARTICLES.QTETOT,
    TAB_TYP_CASE() -- insertion collection vide
  )
  ;

Déclencheur When-New-Record-Instance
Declare
   LC$Req  Varchar2(256) ;
Begin
   If :ARTICLES.CODE Is not null Then
      -- requête dynamique du bloc secondaire --
      LC$Req := '(SELECT cases.EMP, cases.QTE FROM TABLE ( SELECT cases FROM articles WHERE code = ''' 
        || :ARTICLES.CODE || ''') cases)' ;
      Go_Block('CASES' );
      Clear_Block ;
      Set_Block_Property( 'CASES', QUERY_DATA_SOURCE_NAME, LC$Req ) ;
      Execute_Query ;
      Go_Block('ARTICLES') ;
   Else
      Go_Block('CASES' );
      Clear_Block ;
      Go_Block('ARTICLES') ;
   End if ;
End ;

Déclencheur : ON-INSERT
-- Insertion d'une ligne dans la collection --
INSERT INTO TABLE
 (  
   SELECT
      cases
   FROM
      articles
   WHERE
      code = :ARTICLES.CODE
 )
 Values
 (
   TYP_CASE( :CASES.EMP, :CASES.QTE )
 );

Déclencheur : ON-UPDATE
-- Mise à jour de la ligne de la collection --
UPDATE TABLE
 (  
   SELECT
      cases
   FROM
      articles
   WHERE
      code = :ARTICLES.CODE
 ) cases
 SET
   VALUE(cases) = TYP_CASE( :CASES.EMP, :CASES.QTE ) 
 WHERE
   cases.emp = :CASES.EMP
 ;

Déclencheur : ON-DELETE
-- Suppression de la ligne de la collection --
DELETE FROM TABLE
 (  
   SELECT
      cases
   FROM
      articles
   WHERE
      code = :ARTICLES.CODE
 ) cases
 WHERE
   cases.emp = :CASES.EMP
 ;

Déclencheur : ON-LOCK
   Null ;

Techniques avancées

Les blocs basés sur une table objet

Définition

Concept

• ON-INSERT
• ON-UPDATE
• ON-DELETE

Mise en oeuvre

Script de création des objets
-- Type Emplacement --
CREATE OR REPLACE TYPE TYP_EMP AS OBJECT
 (
   EMP   VARCHAR2(10),
   ART   VARCHAR2(20),
   QTE   NUMBER
 )
/

-- Type référence emplacement --
CREATE OR REPLACE TYPE REF_TYP_EMP AS OBJECT
(
  ref_emp REF TYP_EMP
)
/  

-- Table de références emplacements --
CREATE OR REPLACE TYPE TAB_REF_TYP_EMP AS TABLE OF REF_TYP_EMP
/

-- Type objet Articles --
CREATE OR REPLACE TYPE TYP_ARTICLES AS OBJECT
(
  CODE     VARCHAR2 (20), 
  LIBELLE  VARCHAR2 (100), 
  PRIX     NUMBER (8,2), 
  QTETOT   NUMBER (8), 
  REMP     TAB_REF_TYP_EMP
)
/

-- Table objet ARTICLES --
 CREATE TABLE ARTICLES_OBJ OF TYP_ARTICLES 
 NESTED TABLE REMP STORE AS REMP_NT
/

-- Table objet EMPLACEMENTS --
 CREATE TABLE EMP_OBJ OF TYP_EMP 
/

• EMP de type Varchar2(20)
• QTE de type NUMBER

Déclencheur : ON-INSERT
------------------------------------------------
--  l' insertion est effectuée explicitement  --
--  car le nouvel enregistrement ne peut pas  --
--  contenir une collection NULL              --
------------------------------------------------
INSERT INTO ARTICLES_OBJ 
VALUES
(
  TYP_ARTICLES
   ( 
      :ARTICLES.CODE, 
      :ARTICLES.LIBELLE, 
      :ARTICLES.PRIX, 
      :ARTICLES.QTETOT, 
      TAB_REF_TYP_EMP() - collection vide
   )
) ;

Déclencheur : WHEN-NEW-RECORD-INSTANCE
Declare
   LC$Req  Varchar2(256) ;
Begin
   If :ARTICLES.CODE Is not null Then
      ------------------------------------------
      -- requête dynamique du bloc secondaire --
      ------------------------------------------	  
      LC$Req := '(SELECT emp.ref_emp.emp EMP, emp.ref_emp.qte QTE FROM ' ;
      LC$Req := LC$Req || 'TABLE( SELECT REMP FROM articles_obj WHERE CODE = ''' ;
      LC$Req := LC$Req || :ARTICLES.CODE || ''') emp WHERE emp.ref_emp.art = ''' || :ARTICLES.CODE || ''')' ;
	    
      Go_Block('CASES' );
      Clear_Block ;
      Set_Block_Property( 'CASES', QUERY_DATA_SOURCE_NAME, LC$Req ) ;
      Execute_Query ;
      Go_Block('ARTICLES') ;
   Else
      Go_Block('CASES' );
      Clear_Block ;
      Go_Block('ARTICLES') ; 
   End if ;
End ;

Déclencheur : ON-INSERT
-- Insertion d'une ligne (REF) dans la collection --
Declare
	LC$Req Varchar2(256) ;
Begin	
	LC$Req := 'INSERT INTO TABLE
	( SELECT remp FROM ARTICLES_OBJ WHERE code = ''' || :ARTICLES.CODE  || ''')
	VALUES
	( REF_TYP_EMP ( (SELECT REF(a) FROM EMP_OBJ a WHERE a.ART = ''' 
	  || :ARTICLES.CODE || ''' AND a.EMP = ''' || :CASES.EMP || ''') ) )' ;
	
	Forms_Ddl( LC$Req ) ;
End ;

Déclencheur : ON-DELETE
-- Suppression de la ligne (REF) de la collection --
DELETE FROM TABLE
( SELECT remp FROM ARTICLES_OBJ WHERE code = :ARTICLES.CODE ) emp
WHERE 
   emp.ref_emp.art = :ARTICLES.CODE
And
   emp.ref_emp.emp = :CASES.EMP 
;

Déclencheur : ON-LOCK
   Null ;

Déclencheur : KEY-COMMIT
Declare
   LN$Cpt pls_integer ;
   LN$Cur pls_integer ;
Begin	
   -- Enregistrement --
   Commit_form ;

   -- Mise à jour de la quantité totale
   -- pour l'article en cours
   UPDATE ARTICLES_OBJ
   SET   QTETOT = (
   SELECT 
      SUM(emp.ref_emp.qte)
   FROM 
      TABLE( SELECT REMP FROM articles_obj WHERE CODE = :ARTICLES.CODE ) emp
   WHERE 
      emp.ref_emp.art = :ARTICLES.CODE
   )
   WHERE CODE = :ARTICLES.CODE    
   ;
		
   Forms_Ddl( 'commit' ) ;
		
   -- Raffraichissement de l'écran --
   Go_block('ARTICLES');
   LN$Cur := :SYSTEM.CURSOR_RECORD ;
   Execute_query ;
   Go_Record( LN$Cur ) ;
		
End ;

Techniques avancées

INSERT INTO ARTICLES_OBJ VALUES
(
  TYP_ARTICLES( 'ART02', 'Article 2', 12, 10, 
  TAB_REF_TYP_EMP
  ( 
     REF_TYP_EMP ( (SELECT REF(a) FROM EMP_OBJ a WHERE a.ART = ... AND a.EMP = ...) )
  )
  )  
) ;

Declare
  LR$Ref  REF EMP_OBJ ;
Begin
  Select
     Ref(a)
  Into
     LR$Ref
  From
     EMP_OBJ
  ...