Le guide Oracle Forms 9i/10g

Date de publication : Juin 2005

Les alertes

Définition

Concept

Integer := Show_Alert( nom_alerte | id_alerte )

• Stop
• Avertissement
• Remarque

• ALERT_BUTTON1
• ALERT_BUTTON2
• ALERT_BUTTON3

Mise en oeuvre

Création d'une alerte

Cliquer sur le nœud : Alertes dans le navigateur d'objets puis sur l'icône
Une nouvelle boite d'alerte est créée avec un nom attribué par le système.

Faire un double-clic sur le nœud de la nouvelle alerte pour afficher la palette de propriétés.

Set_Alert_Property( nom_alerte | id_alerte, TITLE, nouveau_titre ) ;

Set_Alert_Property( nom_alerte | id_alerte, ALERT_MESSAGE_TEXT, nouveau_texte ) ;

Set_Alert_Button_Property( nom_alerte | id_alerte, numéro_bouton, LABEL, nouveau_libellé ) ;

• ALERT_BUTTON1
• ALERT_BUTTON2
• ALERT_BUTTON3

ALERT := Find_Alert( nom_alerte ) ;

Declare
  Al_id      ALERT ;
  LI$Bouton  pls_integer ;
Begin
  Al_id := Find_Alert( 'mon_alerte' ) ;
  If Id_Null( Al_id ) Then
     Message('la boite d''alerte mon_alerte n''existe pas dans la forme');
     Raise Form_Trigger_Failure ;
  Else
     LI$Bouton := Show_Alert( 'mon_alerte' ) ;
     If LI$Bouton := ALERT_BUTTON1 Then
        ...
     Elseif LI$Bouton := ALERT_BUTTON2 Then
        ...
     Else
        ...
     End if ;
  End if ;
End ;

Techniques avancées

• Inutile d'ouvrir le module pour modifier un message (pas assez explicite pour l'utilisateur, faute d'orthographe, etc.).
• Externalisation des messages applicatifs (les message sont saisis/modifiés en table à l'aide d'un écran Forms ou d'un insert/update direct en table).
• Utilisation de messages paramétrés (les valeurs exactes sont transmises à la fonction d'affichage) permettant de réduire le nombre de messages de base.
• Facilité de traduction (votre système de messagerie peut tenir compte de la langue de l'utilisateur et d'afficher les libellés dans la bonne traduction).

PROCEDURE Affiche_message
	(
		PN$Code in Number,
		PC$Rep1 In Varchar2 Default Null,
		PC$Rep2 In Varchar2 Default Null,
		PC$Rep3 In Varchar2 Default Null,
		PB$Arret In Boolean Default NULL
	) IS
	
  -- Procedure Affiche_message
  --
  -- Affichage d'un message stocké en table
  --
  -- Entree     : PN$Code    Code du message 
  --            : PC$Rep1    Paramètre optionnel de remplacement
  --            : PC$Rep2    Paramètre optionnel de remplacement
  --            : PC$Rep3    Paramètre optionnel de remplacement
  --            : PB$Arret   Flag booleen d'arrêt de surcharge
  --            :            du flag stocké dans le message
  --            :            s'il est renseigné, il annule et remplace
  --            :            la valeur de MESSAGE.STOP
  -- Sortie		:
  -- Ent/Sortie	:
  --
   LR$MESSAGE   MESSAGES%ROWTYPE ;
   LC$Text      Varchar2(300);
   LN$But       Number ;
   Al_id        Alert ;
BEGIN
	
   Select
      *
   Into
      LR$Message
   From
      MESSAGES
   Where
      CODE = PN$Code
   ;
	
   LC$Text := LR$Message.TEXTE ;
	
   -- Retour ligne ? --
   LC$Text := Replace( LC$Text, '|', CHR(10) ) ;
	
   -- Remplacements --
   If PC$Rep1 is not null Then
      LC$Text := Replace( LC$Text, '%1', PC$Rep1 ) ;
   End if ;
   If PC$Rep2 is not null Then
      LC$Text := Replace( LC$Text, '%2', PC$Rep2 ) ;
   End if ;
   If PC$Rep3 is not null Then
      LC$Text := Replace( LC$Text, '%3', PC$Rep3 ) ;
   End if ;
	
   Al_id := Find_Alert(LR$Message.ALERTE); 
   IF Not Id_Null(al_id) THEN 
	
      -- Titre alerte --
      If LR$Message.TITRE is not null Then
         Set_Alert_Property(LR$Message.ALERTE, TITLE, LR$Message.TITRE ) ;
      End if ;
      -- Message --
      Set_Alert_Property(LR$Message.ALERTE, ALERT_MESSAGE_TEXT, LC$Text ) ;
	
      LN$But := Show_Alert(LR$Message.ALERTE);

   Else
      Message('Alerte ' || LR$Message.ALERTE || ' non présente dans la forme');
      Message(LC$TExt);
   End if ;
	
   -- Raise --
   If PB$Arret is not null Then
      If PB$Arret = TRUE Then
         Raise form_trigger_failure ;
      End if ;
   Elsif LR$Message.STOP = 'O' Then
      Raise form_trigger_failure ;		
   End if ;
	
Exception
   When no_data_found Then
      Al_id := Find_Alert('AL_ERREUR'); 
      IF Not Id_Null(al_id) THEN 
         Set_Alert_Property('AL_ERREUR', TITLE, 'Messages applicatifs' );
         Set_Alert_Property('AL_ERREUR', ALERT_MESSAGE_TEXT, 'Message : ' 
          || To_char(PN$Code) || ' non trouvé');
         LN$But := Show_Alert('AL_ERREUR' ) ;
      Else
         Message('Alerte AL_ERREUR non présente dans la forme');
         Message('Message : ' || To_char(PN$Code) || ' non trouvé');
      End if ;
      Raise Form_trigger_failure ;
	
   When Form_trigger_failure Then
      Raise ;
   When others Then
      Null ;
END;